Портал L-¤-D™: Контент / Total Commander / Мгновенная загрузка и обновление Total Commander

Автор: L-¤-D™
не оценено -

Мгновенная загрузка и обновление Total Commander

Как вы обновляете свой рабочий Total Commander?
Некоторые скажут, да проще пареной репы и полезут в интернет искать ссылки на загрузку дистрибутива и ... тонна телодвижений
Некоторые скажут: "О, это очень сложно..."

Немного посидев и пораскинув мыслями я решил упростить эту задачу до 1 клика
Примем во внимание, что ресурс slo.ru на данный момент является вполне надёжным и достаточно хорошо обновляемым

Для достижения результата нам понадобятся:
— пара текстовых файлов
— 2 мощные утилиты, а именно, wget64 (wget) и 7z

Итак, dl_upd_total.cmd

Код:

@echo off
 
:: файл проверяет на новую версию (x64), загружает новый дистрибутив TC с сайта ghisler.com (http://ghisler.com/amazons3.php), распаковывает его и заменяет указанные файлы
 
set "site=http://ghisler.com/amazons3.php"
 
for /f "tokens=2 delims==>" %%a in ('wget64 -nv -O- %site%^|findstr /c:"64-bit version only"') do wget64 -N -nd -c -t 0 %%a
for /f %%a in ('dir /b *.exe') do set tc_n=%%~na
set tc_f=%tc_n%.exe
echo "%tc_f%"
set c=%commander_path%
set t=[%tc_n%]
7z e -aoa -o%t% %tc_f% install.cab
pushd %t%
echo "%cd%"
7z x -r -aoa install.cab totalcmd64.exe
del/q install.cab
popd
start/w/min "" cscript //e:vbscript Total_Close.vbs
:: tasklist|findstr/i totalcmd64.exe||echo Не удалось закрыть ТС с помощью скрипта&taskkill /f /im totalcmd64.exe
xcopy/ichrky %t%\totalcmd64.exe %c%\
rd/s/q %t%
start "" %c%\totalcmd64

Total_Close.vbs

Код:

set w=CreateObject("WScript.Shell")
w.Run("%commander_path%\totalcmd64 /o"),1,1
WScript.Sleep 100
w.SendKeys("%{F4}")
WScript.Sleep 400

Утилиты вы можете положить рядом с нашими файлами или поместить в %path%
В противном случае пропишите полные пути до утилит и наших файлов в приведенном коде

Код можно повесить на кнопку или на горячую клавишу
Если есть вопросы, задавайте, не стесняйтесь
Удачи